Crypt::Mode::CBC(3p)

NAME
Crypt::Mode::CBC - Block cipher mode CBC [Cipher-block chaining]

SYNOPSIS
   use Crypt::Mode::CBC;
   my $m = Crypt::Mode::CBC->new('AES');
   my $key = '1234567890123456';
   my $iv = '1234567890123456';
   my $plaintext = 'example plaintext';
   my $chunk1 = 'example ';
   my $chunk2 = 'plaintext';

   # encrypt or decrypt in one call
   my $single_ciphertext = $m->encrypt($plaintext, $key, $iv);
   my $single_plaintext = $m->decrypt($single_ciphertext, $key, $iv);

   # encrypt more chunks
   $m->start_encrypt($key, $iv);
   my $chunked_ciphertext = '';
   $chunked_ciphertext .= $m->add($chunk1);
   $chunked_ciphertext .= $m->add($chunk2);
   $chunked_ciphertext .= $m->finish;

   # decrypt more chunks
   $m->start_decrypt($key, $iv);
   my $chunked_plaintext = '';
   $chunked_plaintext .= $m->add($chunked_ciphertext);
   $chunked_plaintext .= $m->finish;

DESCRIPTION
This module implements CBC cipher mode. Note: It works only with ciphers from CryptX (Crypt::Cipher::NNNN).

METHODS
Unless noted otherwise, assume $m is an existing mode object created via "new", for example:

 my $m = Crypt::Mode::CBC->new('AES');

  new
 my $m = Crypt::Mode::CBC->new($name);
 #or
 my $m = Crypt::Mode::CBC->new($name, $padding);
 #or
 my $m = Crypt::Mode::CBC->new($name, $padding, $cipher_rounds);

 # $name ....... [string] one of 'AES', 'Anubis', 'Blowfish', 'CAST5', 'Camellia', 'DES', 'DES_EDE',
 #               'KASUMI', 'Khazad', 'MULTI2', 'Noekeon', 'RC2', 'RC5', 'RC6',
 #               'SAFERP', 'SAFER_K128', 'SAFER_K64', 'SAFER_SK128', 'SAFER_SK64',
 #               'SEED', 'Skipjack', 'Twofish', 'XTEA', 'IDEA', 'Serpent'
 #               or any <NAME> for which there is a Crypt::Cipher::<NAME> module
 # $padding .... [integer] 0 no padding (plaintext size has to be multiple of block length)
 #               1 PKCS5 padding, Crypt::CBC's "standard" - DEFAULT
 #               2 Crypt::CBC's "oneandzeroes"
 #               3 ANSI X.923 padding
 #               4 zero padding
 #               5 zero padding (+a block of zeros if the output length is divisible by the blocksize)
 # $cipher_rounds ... [integer] optional, number of rounds for given cipher

  encrypt
Encrypts the plaintext in a single call. Returns the ciphertext as a binary string. The plaintext scalar is converted to bytes using Perl's usual scalar stringification. Defined scalars, including numbers and string-overloaded objects, are accepted. "undef" is treated as an empty string and may emit Perl's usual "uninitialized value" warning.

   my $ciphertext = $m->encrypt($plaintext, $key, $iv);

  decrypt
Decrypts the ciphertext in a single call. Returns the plaintext as a binary string. The ciphertext scalar is converted to bytes using Perl's usual scalar stringification. Defined scalars, including numbers and string-overloaded objects, are accepted. "undef" is treated as an empty string and may emit Perl's usual "uninitialized value" warning.

   my $plaintext = $m->decrypt($ciphertext, $key, $iv);

  start_encrypt
Initializes encryption mode. Returns the object itself.

   $m->start_encrypt($key, $iv);

  start_decrypt
Initializes decryption mode. Returns the object itself.

   $m->start_decrypt($key, $iv);

  add
Feeds data to the encryption or decryption stream. Returns a binary string.

Each argument is converted to bytes using Perl's usual scalar stringification. Defined scalars, including numbers and string-overloaded objects, are accepted. "undef" is treated as an empty string and may emit Perl's usual "uninitialized value" warning.

   # in encrypt mode
   my $ciphertext = $m->add($plaintext);

   # in decrypt mode
   my $plaintext = $m->add($ciphertext);

  finish
Finalizes the stream. In encryption mode, pads and encrypts the final block; in decryption mode, decrypts and removes padding from the final block. Returns the result as a binary string (may be empty if there is no data to flush).

   # encrypt more chunks
   $m->start_encrypt($key, $iv);
   my $chunk1 = 'example ';
   my $chunk2 = 'plaintext';
   my $ciphertext = '';
   $ciphertext .= $m->add($chunk1);
   $ciphertext .= $m->add($chunk2);
   $ciphertext .= $m->finish;

   # decrypt more chunks
   $m->start_decrypt($key, $iv);
   my $plaintext = '';
   $plaintext .= $m->add($ciphertext);
   $plaintext .= $m->finish;

SEE ALSO

•   CryptX, Crypt::Cipher

•   Crypt::Cipher::AES, Crypt::Cipher::Blowfish, ...

•   <https://en.wikipedia.org/wiki/Block_cipher_mode_of_operation#Cipher-block_chaining_.28CBC.29>